#!/bin/csh 

#---------------------------
# print help messages
#---------------------------
      
set helpheader = 0
set helparg = 0
if ($#argv < 1) then
  set helpheader = 1
else
  set i = `echo $argv[1]|cut -c2-`
  if( $i == "help" ) then
    set helpheader = 1
    set helparg = 1
  endif
endif
      
if ( $helpheader ) then
cat <<EOF

NAME

   create_production_test  
                                               
SYNOPSIS

   create_production_test -mach     mach    
                          -testroot testroot 

   create_production_test -help

EOF

if ( $helparg ) then
cat <<EOF
************************************************************************
Purposes 
************************************************************************
 
   to clone the current caseroot, (restart, branch, or hybrid) 
   and to create a 60-day restart test on the cloned case.
 
************************************************************************
Requirements 
************************************************************************
 
1) This scripts must exist in the caseroot that's been tested.

2) For branch or hybrid run, initial data must exist in
      /ptmp/CCSMUSER/archive/CASE/restart
                                                                                    c
3) -mach mach         
   User must input machine name.    
   It is the name of the machine this test is running on,
   e.g. -mach bluevista.
                                                                                    c
4) -testroot testroot 
   User must input testroot.    
   testroot specifies the directory where this test will run,
   e.g. -testroot /ptmp/user.
                                                                                    c
5) After running this script,                               
   user must submit to run the test script,
   and check the test status.
 
----------------------------------------------------------------------
 
EXAMPLES

(1) create_production_test -mach     bluevista                
                           -testroot /ptmp/user
 
(2) create_production_test -mach     phoenix                  
                           -testroot /scratch/scr101/user
 
EOF
endif
exit
endif
      
#---------------------------
# check input arguments
#---------------------------

if ( $#argv < 4 ) then
   echo "ERROR: must provide 4 required input arguments"
   exit -1
endif

while ( 1 )
  if ( $#argv < 1 ) break;
  set i = $argv[1];
### check the error of the input argument.
      shift argv
      if($#argv <1 ) then
          echo "ERROR in ${0}: Please input the content for $i."
          exit -1
      endif
      set ywtmp = "-"
      if( $argv[1] =~ $ywtmp* ) then
          echo "ERROR in ${0}: wrong argument for $i.";
          exit -1
      endif
### end of check the error for the input argument
 
#---------------------------
# get input arguments   
#---------------------------
      
  switch ( $i )
    case "-mach"
      set mach     = $argv[1]
      breaksw
    case "-testroot"
      set testroot = $argv[1]
      breaksw
    default:
      echo "unknown input, invoke create_production_test with no arguments for usage"
      exit -1
      breaksw
  endsw
  shift argv
end
      
#===================================================================
# check env settings
#===================================================================
                                             
# --- check machine ---
if (! $?mach ) then
   echo "ERROR: must input mach"
   exit -1
endif
 
# --- check testroot ---
if (! $?testroot ) then
   echo "ERROR: must input testroot"
   exit -1
else
   if !( -e $testroot ) then
      echo "ERROR: testroot $testroot does not exist"
      exit -1
   endif
endif
      
#===================================================================
# type of test case in scripts/ccsm_utils/Testcases
#===================================================================
 
set type = ERP
 
echo ""
echo "creating test type $type"
 
#===================================================================
# get env settings
#===================================================================
                     
source env_conf
source env_run
source env_mach.$mach

#===================================================================
# get clone name and execute directory
#===================================================================

set caseroot  = $CASEROOT
set casename  = $CASE
set clonename = clone_$casename

#=======================================================================
# check type        
#=======================================================================
 
if !( -e $UTILROOT/Testcases/$type ) then
      echo "ERROR: $UTILROOT/Testcases/$type does not exist"
      exit -1
endif
 
#=======================================================================
# get dataroot for branch and hybrid
#=======================================================================
 
if ( $RUN_TYPE != "startup" ) then
   set dataroot = $testroot/archive/$casename/restart
 
   if !( -e $dataroot ) then
      echo "ERROR: dataroot for branch/hybrid does not exist"
      exit -1
   else
      if !( -e $$testroot/archive/$clonename ) then
         mkdir $testroot/archive/$clonename
         cp -r $dataroot $testroot/archive/$clonename/restart
      endif
      echo "dataroot is $dataroot"
   endif
endif
 
#=======================================================================
# create clone case
#=======================================================================
 
if ( -e $testroot/$clonename ) then
   echo "removing previous $testroot/$clonename"
   rm -rf $testroot/$clonename 
endif

cd $SCRIPTSROOT         
./create_newcase -case $testroot/$clonename -clone $caseroot

#===================================================================
# Modify env_conf, env_run and env_mach.machine in test directory 
#===================================================================

cd $testroot/$clonename
 
set tenvconf = `$UTILROOT/Tools/ccsm_readvalue $UTILROOT/Testcases/$type env_conf`
set tenvrun  = `$UTILROOT/Tools/ccsm_readvalue $UTILROOT/Testcases/$type env_run`
set tenvmach = `$UTILROOT/Tools/ccsm_readvalue $UTILROOT/Testcases/$type env_mach`

$UTILROOT/Tools/ccsm_sedfile env_conf $tenvconf
if ($status != 0) then
  echo "ERROR: ccsm_sedfile failed"
  exit -1
endif
$UTILROOT/Tools/ccsm_sedfile env_run $tenvrun
if ($status != 0) then
  echo "ERROR: ccsm_sedfile failed"
  exit -1
endif
$UTILROOT/Tools/ccsm_sedfile -nocheck env_mach.$mach $tenvmach
if ($status != 0) then
  echo "ERROR: ccsm_sedfile failed"
  exit -1
endif

source ./env_conf       || exit -1
source ./env_run        || exit -1
source ./env_mach.$mach || exit -1

#===================================================================
# create run script (that test script will call)
#===================================================================
 
cd ${CASEROOT}
./configure -mach4test $mach
 
#===================================================================
# create test script
#===================================================================
 
cd ${UTILROOT}/Machines
set arch = `echo $ARCH | tr '[A-Z]' '[a-z]'`

./batch.${arch}.${mach} || exit -1  

cd ${CASEROOT}

mv $CASE.$mach.run $CASE.test

# fill in the rest of the test script...
cat >> ${CASE}.test << EOF

cd $CASEROOT
setenv MACH       $mach
setenv CASEBASEID $clonename
 
source env_conf         || "problem sourcing env_conf"    && exit -1  
source env_run          || "problem sourcing env_run"     && exit -1  
source env_mach.\$MACH   || "problem sourcing env_mach.\$MACH" && exit -1
source env_pes.\$MACH    || "problem sourcing env_pes.\$MACH" && exit -1
source $CASETOOLS/env_setcomp  || "problem sourcing env_setcomp"   && exit -1

EOF
 
cat $UTILROOT/Tools/testcase_begin >>     $CASE.test || exit -1
cat $UTILROOT/Testcases/${type}_script >> $CASE.test || exit -1
cat $UTILROOT/Tools/testcase_end >>       $CASE.test || exit -1

#===================================================================
# copy over compare script
#===================================================================
cp $UTILROOT/Tools/restart_compare.pl . || exit -1

chmod 755 $CASE* *pl

echo ""
echo "*************************************************************"
echo "Please submit to run $testroot/$clonename/$clonename.test"
echo "   e.g. bsub <   $testroot/$clonename/$clonename.test"
echo "        qsub     $testroot/$clonename/$clonename.test"
echo "        llsubmit $testroot/$clonename/$clonename.test"
echo "and check $testroot/$clonename/TestStatus for PASS or FAIL"
echo "   e.g. less $testroot/$clonename/TestStatus"
echo "*************************************************************"
echo ""